blob: 64dd2b1cb3a8e2c173dedf3587fb91cc1d430c64 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Maintainer: Zarloc <nichocolat@gmail.com>
# Contributor: Alessio <alessio@linux.com>
pkgname=k9s-git
_pkgname=k9s
pkgver=v0.40.4.r1.gab6454f1
pkgrel=1
pkgdesc='Kubernetes TUI for managing clusters and pods'
arch=(x86_64)
url='https://github.com/derailed/k9s'
license=(Apache-2.0)
makedepends=(git go)
depends=(glibc)
options=('!lto')
provides=(k9s)
conflicts=(k9s)
source=("git+$url")
sha256sums=('SKIP')
pkgver() {
cd $_pkgname
( set -o pipefail
git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
)
}
prepare() {
cd $_pkgname
GOFLAGS="-mod=readonly" go mod vendor -v
}
build() {
cd $_pkgname
export LDFLAGS+=' -Wl,-z,shstk'
export CGO_LDFLAGS="$LDFLAGS"
export CGO_CFLAGS="$CFLAGS"
export CGO_CPPFLAGS="$CPPFLAGS"
export CGO_CXXFLAGS="$CXXFLAGS"
export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"
export GOPATH="$srcdir"
local ld_flags=" \
-X github.com/derailed/k9s/cmd.commit=$(git rev-parse --short HEAD) \
-X github.com/derailed/k9s/cmd.date=NOTSET \
-X github.com/derailed/k9s/cmd.version=$pkgver \
-compressdwarf=false \
-linkmode=external \
"
go build -v -ldflags "$ld_flags" -tags=netgo -o execs/k9s main.go
}
check() {
cd $_pkgname
go test ./...
}
package() {
cd $_pkgname
execs/k9s completion bash | install -Dm644 /dev/stdin "$pkgdir/usr/share/bash-completion/completions/k9s"
execs/k9s completion zsh | install -Dm644 /dev/stdin "$pkgdir/usr/share/zsh/site-functions/_k9s"
execs/k9s completion fish | install -Dm644 /dev/stdin "$pkgdir/usr/share/fish/vendor_completions.d/k9s.fish"
install -Dm755 "execs/$_pkgname" "$pkgdir/usr/bin/$_pkgname"
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$_pkgname/LICENSE"
}
# vim: ts=2 sw=2 et:
|