PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: Bart De Vries <bart at mogwai dot be>
# Contributor: Gustavo Castro < gustawho [ at ] gmail [ dot ] com >

pkgname=kasts-git
pkgver=24.04.70_r1560.g7e1e8f68
pkgrel=1
arch=('x86_64' 'armv7h' 'aarch64')
pkgdesc="Kirigami-based podcast player"
url="https://invent.kde.org/multimedia/kasts"
license=('GPL2')
depends=('qt6-multimedia' 'qt6-declarative' 'qtkeychain-qt6' 'kirigami' 'ki18n'
         'kconfig' 'kcoreaddons' 'syndication' 'taglib' 'threadweaver' 'vlc'
         'kirigami-addons' 'qqc2-desktop-style')
makedepends=('extra-cmake-modules' 'git' 'qt6-svg' 'qt6-tools')
conflicts=("${pkgname%-git}")
provides=("${pkgname%-git}")
source=("git+${url}.git")
sha256sums=('SKIP')

pkgver() {
  cd "${pkgname%-git}"
  ( set -o pipefail
    _major_ver="$(grep -m1 'set *(RELEASE_SERVICE_VERSION_MAJOR' CMakeLists.txt | cut -d '"' -f2)"
    _minor_ver="$(grep -m1 'set *(RELEASE_SERVICE_VERSION_MINOR' CMakeLists.txt | cut -d '"' -f2)"
    _micro_ver="$(grep -m1 'set *(RELEASE_SERVICE_VERSION_MICRO' CMakeLists.txt | cut -d '"' -f2)"
    echo "${_major_ver}.${_minor_ver}.${_micro_ver}_r$(git rev-list --count HEAD).g$(git rev-parse --short HEAD)"
  )
}

build() {
  cmake -DCMAKE_INSTALL_PREFIX=/usr \
    -DQT_MAJOR_VERSION=6 \
    -DCMAKE_BUILD_TYPE=RelWithDebInfo \
    -B build \
    -S "${pkgname%-git}"
  cmake --build build --config RelWithDebInfo
}

package() {
  DESTDIR="${pkgdir}" cmake --install build --config RelWithDebInfo
}