PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

# Maintainer: tarball <bootctl@gmail.com>

pkgname=kbd-audio
pkgver=2022.05.03
pkgrel=1
pkgdesc='Acoustic keyboard eavesdropping'
arch=(i686 x86_64 aarch64)
url='https://github.com/ggerganov/kbd-audio'
license=(MIT)
depends=(sdl2 fftw libglvnd)
makedepends=(cmake)
source=("$pkgname-$pkgver::git+$url.git#tag=keytap3")
sha256sums=('SKIP')

prepare() {
  cd $pkgname-$pkgver
  git submodule update --init
}

build() {
  cmake -B build -S "$srcdir/$pkgname-$pkgver" \
    -DCMAKE_BUILD_TYPE='None' \
    -DCMAKE_INSTALL_PREFIX=/usr

  cmake --build build
}

package() {
  local bins=(
    compress-n-grams
    key-detector
    keytap
    keytap-gui
    keytap2
    keytap2-gui
    keytap3
    keytap3-app
    keytap3-gui
    play
    play-full
    record
    record-full
    view-full-gui
    view-gui
  )

  for bin in "${bins[@]}"; do
    install -Dm755 "build/$bin" "$pkgdir/usr/bin/kbd-$bin"
  done

  install -Dm755 "$srcdir/$pkgname-$pkgver/LICENSE" \
    "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}