PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Maintainer: Yurii Kolesnykov <root@yurikoles.com>
# Contributor: Solomon Choina <shlomochoina@gmail.com>
#
# Pull Requests are welcome here: https://github.com/yurikoles-aur/kcm-grub2-git
#

pkgname=kcm-grub2-git
_product="${pkgname%-git}"
pkgver=0.6.4.r280.gef91a2a
_branch='work/nico/qt6'
pkgrel=1
pkgdesc="A KDE Control Module for configuring the GRUB2 bootloader"
arch=('x86_64')
url='https://invent.kde.org/system/kcm-grub2'
license=('GPL-3.0-or-later')
depends=(
	'grub'
	'hwinfo'
	'kcmutils'
	'libmagick'
)
makedepends=(
    'cmake'
	'extra-cmake-modules'
	'git'
	'packagekit-qt6'
)
conflicts=('grub2-editor-frameworks')
provides=('grub2-editor-frameworks')
optdepends=(
	'os-prober: To detect other OSes when generating grub.cfg in BIOS systems'
	'packagekit-qt6'
)
source=("${_product}::git+${url}.git#branch=${_branch}")
sha256sums=('SKIP')

pkgver() {
	cd "${_product}"
	# cutting off 'v' prefix that presents in the git tag
	git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
	cmake -B build -S "${_product}" \
		-D BUILD_TESTING=OFF \
		-Wno-dev
	cmake --build build
}

package() {
	DESTDIR="${pkgdir}" cmake --install build
}