PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

pkgname=kigo-git
pkgver=v14.12.0.59.g62e3750
pkgrel=1
pkgdesc="An open-source implementation of the popular Go game. (GIT version)"
arch=('i686' 'x86_64')
url='https://www.kde.org/applications/games/kigo/'
license=('GPL')
depends=('qt5-base'
         'qt5-svg'
         'kcoreaddons'
         'kconfig'
         'kcrash'
         'kdbusaddons'
         'kdoctools'
         'kconfigwidgets'
         'ktextwidgets'
         'kxmlgui'
         'kio'
         'knotifyconfig'
         'knewstuff'
         'hicolor-icon-theme'
         'libkdegames'
         )
makedepends=('extra-cmake-modules'
             'git'
             )
conflicts=('kdegames-kigo')
source=('git://anongit.kde.org/kigo.git#branch=frameworks')
sha1sums=('SKIP')

pkgver() {
  cd kigo
  echo "$(git describe --long --tags | tr - .)"
}

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../kigo \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DLIB_INSTALL_DIR=lib \
    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON \
    -DBUILD_TESTING=OFF
  make
}

package() {
  make -C build DESTDIR="${pkgdir}" install
}