PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# based on the kmix (KF5) PKGBUILD:
#   Maintainer: Antonio Rojas <arojas@archlinux.org>
#   Maintainer: Felix Yan <felixonmars@archlinux.org>
#   Contributor: Andrea Scarpino <andrea@archlinux.org>
# Maintainer: Martin Blumenstingl <martin.blumenstingl@googlemail.com>

pkgname=kmix-kf6-git
pkgver=r2761.5b617eb
pkgrel=1
pkgdesc='KDE volume control program'
url='https://apps.kde.org/kmix/'
arch=(x86_64)
license=(GPL-2.0-or-later LGPL-2.0-or-later)
depends=(alsa-lib
         gcc-libs
         glibc
         kconfig
         kconfigwidgets
         kcoreaddons
         kcrash
         kdbusaddons
         kglobalaccel
         ki18n
         knotifications
         kwidgetsaddons
         kwindowsystem
         libcanberra
         libpulse
         qt6-base
         kxmlgui
         sh
         solid)
makedepends=(extra-cmake-modules
             kdoctools)
groups=(kde-applications
        kde-multimedia)
source=("git+https://github.com/KDE/${pkgname%-kf6-git}.git#branch=kf6")
sha256sums=('SKIP')

pkgver() {
  cd ${pkgname%-kf6-git}
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}

build() {
  cmake -B build -S ${pkgname%-kf6-git} \
    -DBUILD_TESTING=OFF \
    -DQT_MAJOR_VERSION=6
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}