PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Maintainer: Carlos Aznarán <caznaranl@uni.pe>
pkgname=kokkos
pkgver=4.4.01
pkgrel=1
pkgdesc="C++ performance portability programming ecosystem"
arch=(x86_64)
url="https://github.com/${pkgname}/${pkgname}"
license=(Apache-2.0)
depends=(bash hwloc)
makedepends=(cmake)
# checkdepends=(gtest)
conflicts=('trilinos')
source=(${pkgname}-${pkgver}.tar.gz::${url}/archive/${pkgver}.tar.gz)
sha256sums=('3f7096d17eaaa4004c7497ac082bf1ae3ff47b5104149e54af021a89414c3682')

build() {
  cmake \
    -S ${pkgname}-${pkgver} \
    -B build \
    -DBUILD_SHARED_LIBS=TRUE \
    -DCMAKE_BUILD_TYPE=None \
    -DCMAKE_CXX_STANDARD=17 \
    -DCMAKE_CXX_COMPILER=g++ \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DKokkos_ENABLE_BENCHMARKS=OFF \
    -DKokkos_ENABLE_CUDA=OFF \
    -DKokkos_ENABLE_DEBUG=OFF \
    -DKokkos_ENABLE_EXAMPLES=OFF \
    -DKokkos_ENABLE_HIP=OFF \
    -DKokkos_ENABLE_HWLOC=ON \
    -DKokkos_ENABLE_HPX=OFF \
    -DKokkos_ENABLE_LIBDL=ON \
    -DKokkos_ENABLE_ONEDPL=OFF \
    -DKokkos_ENABLE_OPENACC=OFF \
    -DKokkos_ENABLE_OPENMP=OFF \
    -DKokkos_ENABLE_ROCM=OFF \
    -DKokkos_ENABLE_SERIAL=ON \
    -DKokkos_ENABLE_SYCL=OFF \
    -DKokkos_ENABLE_TESTS=OFF \
    -DKokkos_ENABLE_THREADS=ON \
    -Wno-dev
  cmake --build build --target all
}

# check() {
#   ctest --test-dir build
# }

package() {
  DESTDIR="${pkgdir}" cmake --build build --target install
  install -Dm644 ${pkgname}-${pkgver}/LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}