PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59

# Maintainer: MithicSpirit <rpc01234 at gmail dot com>

_pkgname=kondo
pkgname=("$_pkgname-git" "$_pkgname-ui-git")
pkgbase="$_pkgname-git"
pkgver=latest
pkgrel=3
epoch=
pkgdesc='Save disk space by cleaning non-essential files from software projects.'
arch=(x86_64)
url="https://github.com/tbillington/$_pkgname"
license=('MIT')
depends=('gcc-libs')
makedepends=('cargo' 'git' 'gtk3')
source=("$_pkgname::git+https://github.com/tbillington/$_pkgname.git")
sha256sums=('SKIP')

prepare() {
	cd "$srcdir/$_pkgname"
	cargo fetch --target "$CARCH-unknown-linux-gnu"

	cd "$_pkgname-ui"
	cargo fetch --target "$CARCH-unknown-linux-gnu"
}

pkgver() {
	cd "$srcdir/$_pkgname"
	git describe --long --tags | sed 's/\([^-]*-\)g/r\1/;s/-/./g;s/^v//g'
}

build() {
	cd "$srcdir/$_pkgname"
	cargo build --frozen --release --all-features
	
	cd "$_pkgname-ui"
	cargo build --frozen --release --all-features
}

package_kondo-git() {
	provides=("$_pkgname")
	conflicts=("$_pkgname")

	cd "$srcdir/$_pkgname"
	install -vDm755 -t "$pkgdir/usr/bin" "target/release/$_pkgname"
	install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
	install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}

package_kondo-ui-git() {
	provides=("$_pkgname-ui")
	conflicts=("$_pkgname-ui")
	depends+=('gtk3')

	cd "$srcdir/$_pkgname"
	install -vDm755 -t "$pkgdir/usr/bin" \
		"$_pkgname-ui/target/release/$_pkgname-ui"
	install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
	install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}