PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Maintainer: Zhirui Dai <daizhirui@hotmail.com>

pkgname=ksvg-git
_name=${pkgname%-git}
pkgver=r5156.aff7a5e0
pkgrel=1
pkgdesc='A library for rendering SVG-based themes with stylesheet re-coloring and on-disk caching'
arch=(x86_64)
url='https://projects.kde.org/projects/playground/libs/plasma-framework'
license=(LGPL)
depends=(
    gcc-libs
    glibc
    karchive
    kcolorscheme
    kconfig
    kguiaddons
    qt6-base 
    qt6-svg
)
makedepends=(
    doxygen
    extra-cmake-modules
    kirigami
    qt6-declarative
    qt6-doc
    qt6-tools
    git
)
optdepends=(
    'kirigami: QML bindings'
    'qt6-declarative: QML bindings'
)
source=("git+https://invent.kde.org/frameworks/$_name.git")
conflicts=(ksvg)
provides=(ksvg)
sha256sums=('SKIP')

pkgver() {
    cd $_name
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
    cmake -B build -S $_name -DCMAKE_BUILD_TYPE=Release -DBUILD_QCH=ON -DBUILD_TESTING=OFF
    cmake --build build
}

package() {
    DESTDIR="$pkgdir" cmake --install build
}