blob: 252aad3d21d7adeb5059345b998184ed7a39abd0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# Maintainer: hekel <hekel at vivaldi dot net>
pkgname=kwin-effects-burn-my-windows-git
_pkgname=Burn-My-Windows-git
pkgver=44.r7.g4538ff3
pkgrel=1
pkgdesc="Disintegrate your windows with style."
arch=('any')
url="https://github.com/Schneegans/Burn-My-Windows"
license=('GPL-3.0-or-later')
depends=('kwin')
makedepends=('git')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("$_pkgname::git+$url.git")
sha256sums=('SKIP')
pkgver() {
cd "$_pkgname"
( set -o pipefail
git describe --long --tags --abbrev=7 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
)
}
build() {
cd "$_pkgname/kwin"
sh build.sh
}
package() {
cd "$_pkgname"
install -dm0755 "$pkgdir/usr/share/kwin/effects"
tar -xf "$srcdir/$_pkgname/kwin/burn_my_windows_kwin6.tar.gz" -C "$pkgdir/usr/share/kwin/effects"
install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}
|