blob: 4e93254983569427d1c52c1e57e5576c0ee3d098 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
# Contributor: Behnam Momeni <sbmomeni [at the] gmail [dot] com>
# Contributor: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Rémy Oudompheng <oudomphe@clipper.ens.fr>
_name="libspiro"
pkgname="lib32-${_name}"
pkgver=20240903
pkgrel=1
pkgdesc="Library that simplifies the drawing of beautiful curves (32-bit)"
arch=('x86_64')
url="https://github.com/fontforge/${_name}"
license=('GPL-3.0-or-later')
depends=('lib32-glibc' "${_name}>=${pkgver}")
makedepends=('lib32-gcc-libs') # unused
provides=("${_name}.so")
_pkgsrc="${_name}-${pkgver}"
source=("${_pkgsrc}.tar.gz::${url}/archive/refs/tags/${pkgver}.tar.gz")
sha256sums=('cf0251eb5f3545cce365b727a4a56a2f1292f1ef29245c2045c83e28f8a1df42')
build() {
export CFLAGS+=" -m32"
export CXXFLAGS+=" -m32"
export LDFLAGS+=" -m32"
export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
cd "${srcdir}/${_pkgsrc}"
autoreconf -vfi
./configure \
--prefix='/usr' \
--program-suffix='-32' \
--lib{exec,}dir='/usr/lib32' \
--build=i686-pc-linux-gnu
make
}
check() {
cd "${srcdir}/${_pkgsrc}"
make check
}
package() {
cd "${srcdir}/${_pkgsrc}"
make DESTDIR="${pkgdir}" install
cd "${pkgdir}/usr"
rm -rf "include" "share"
}
|