PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# Maintainer: Ewout van Mansom <ewout@vanmansom.name>

pkgname=libcollectc-git
pkgver=r616.2302fff
pkgrel=3
pkgdesc='Collections C provides generic data structures for the C programming language.'
arch=('i686' 'x86_64' 'aarch64')
url='https://github.com/srdja/Collections-C'
license=('LGPL3')
depends=('glibc')
makedepends=('git' 'cmake')
checkdepends=('cpputest')
provides=('libcollectc' 'libcollectc.so')
source=('libcollectc-git::git+https://github.com/srdja/Collections-C.git#branch=master')
sha256sums=('SKIP')

pkgver() {
  cd "${pkgname}"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}

build() {
  cmake \
    -B "${pkgname}/build" \
    -S "${pkgname}" \
    -DCMAKE_BUILD_TYPE:STRING='None' \
    -DCMAKE_INSTALL_PREFIX:PATH='/usr' \
    -Wno-dev
  cmake --build "${pkgname}/build"
}

check() {
  cd "${pkgname}"
  ctest --test-dir build --output-on-failure --stop-on-failure -j1
}

package() {
  DESTDIR="${pkgdir}" cmake --install "${pkgname}/build"
}