PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58

# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=libdatachannel-git
pkgver=0.20.3.r45.g1f4d08ab
pkgrel=1
pkgdesc="C/C++ WebRTC network library featuring Data Channels, Media Transport, and WebSockets"
arch=('i686' 'x86_64')
url="https://libdatachannel.org/"
license=('MPL-2.0')
depends=('gcc-libs' 'libjuice' 'libsrtp' 'openssl')
makedepends=('git' 'cmake')
provides=("libdatachannel=$pkgver")
conflicts=('libdatachannel')
source=("git+https://github.com/paullouisageneau/libdatachannel.git")
sha256sums=('SKIP')


prepare() {
  cd "libdatachannel"

  git submodule update --init --recursive
}

pkgver() {
  cd "libdatachannel"

  _tag=$(git tag -l --sort -v:refname | grep -E '^v?[0-9\.]+$' | head -n1)
  _rev=$(git rev-list --count $_tag..HEAD)
  _hash=$(git rev-parse --short HEAD)
  printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}

build() {
  cd "libdatachannel"

  cmake \
    -B "_build" \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX="/usr" \
    -DCMAKE_INSTALL_LIBDIR="lib" \
    -DUSE_SYSTEM_JUICE=ON \
    -DUSE_SYSTEM_SRTP=ON \
    -DNO_EXAMPLES=ON \
    ./
  make -C "_build"
}

check() {
  cd "libdatachannel"

  #make -C "_build" tests
}

package() {
  cd "libdatachannel"

  make -C "_build" DESTDIR="$pkgdir" install
}