blob: 2c217a721c10118aafe30c627bcd7aa82f7a065a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Alyxia Sother <nylkvn@evfrhc.arg(rot13)>
pkgname=libhelium
pkgver="1.8.24"
_pkgver="1.8.24"
pkgrel=1
pkgdesc="The application framework for tauOS apps."
arch=('x86_64' 'aarch64')
depends=('gtk4' 'glib2' 'libgee')
makedepends=(
'dart-sass'
'git'
'gobject-introspection'
'meson'
'ninja'
'vala'
)
url="https://github.com/tau-OS/libhelium"
license=('LGPL3')
source=("$pkgname-$_pkgver.tar.gz::https://github.com/tau-OS/libhelium/archive/refs/tags/$_pkgver.tar.gz"
"$pkgname.patch")
sha256sums=('e2a25fd0a6bc1ec19013355fcb8b18233382920d870707d9c519ef407157214f'
'10cf52c999db7484dc3bf220772cfa58f58c9d539c43c968727251bbf60e8ad6')
prepare() {
cd "$srcdir/libhelium-$_pkgver"
meson subprojects download
# Removes the automatic schema compilation, we're doing this ourselves
patch --strip=1 --input="$srcdir/$pkgname.patch"
}
build() {
cd "$srcdir/libhelium-$_pkgver"
arch-meson . builddir -Dvaladoc=false -Ddemo=false
meson compile -C builddir
}
package() {
cd "$srcdir/libhelium-$_pkgver"
meson install -C builddir --destdir "$pkgdir"
# Manually add the schema into the right data dir.
# We don't have to call glib-compile-schemas as glib2 contains a hook:
# <https://gitlab.archlinux.org/archlinux/packaging/packages/glib2/-/blob/main/glib-compile-schemas.hook?ref_type=heads>
install -Dm644 data/com.fyralabs.desktop.appearance.gschema.xml "$pkgdir/usr/share/glib-2.0/schemas/com.fyralabs.desktop.appearance.gschema.xml"
}
|