PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# Maintainer: Ivan Shapovalov <intelfx@intelfx.name>
# Contributor: Jhon Diaz <electimon@gmail.com>
# Contributor: Matthew Bauer <mjbauer95@gmail.com>

pkgname=libideviceactivation-git
epoch=1
pkgver=1.1.1.r17.gecc10ef
pkgrel=1
pkgdesc="Activates iDevices using a single tool."
arch=('i686' 'x86_64')
url="http://github.com/libimobiledevice/libideviceactivation"
license=('LGPL-2.1-only' 'GPL-3.0-only')
depends=('curl' 'libxml2' 'libplist-git' 'libimobiledevice-git')
makedepends=('git')
provides=(libideviceactivation-1.0.so "libideviceactivation=$pkgver")
conflicts=('libideviceactivation')
source=("git+https://github.com/libimobiledevice/libideviceactivation")
md5sums=('SKIP')

pkgver() {
	cd libideviceactivation
	git describe --long --tags | sed 's/[^-]*-g/r&/;s/-/./g'
}

prepare() {
	cd libideviceactivation
	NOCONFIGURE=1 ./autogen.sh
}

build() {
	cd libideviceactivation
	./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var
	make
}

package() {
	cd libideviceactivation
	make DESTDIR="$pkgdir" install
}