PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34

# Maintainer: Michal Krenek (Mikos) <m.krenek@gmail.com>
pkgname=libmirisdr4-git
pkgver=r33.fd0452e
pkgrel=1
pkgdesc="Support of Mirics MSi001 + MSi2500 SDR devices (yet another flavour of libmirisdr)"
arch=('i686' 'x86_64')
url="https://github.com/f4exb/libmirisdr-4"
license=('GPL')
depends=('libusb>=1.0')
makedepends=('git' 'cmake')
provides=('libmirisdr' 'libmirisdr4' 'libmirisdr-git')
conflicts=('libmirisdr' 'libmirisdr4' 'libmirisdr-git')
source=("${pkgname}::git+https://github.com/f4exb/libmirisdr-4.git")
md5sums=('SKIP')

pkgver() {
    cd "$srcdir/${pkgname}"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
    cd "$srcdir/${pkgname}"
    cmake . \
        -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_INSTALL_PREFIX=/usr
    make
}

package() {
    cd "$srcdir/${pkgname}"
    make DESTDIR="$pkgdir/" install
    mkdir -p "${pkgdir}/etc/udev/rules.d/"
    cp "$srcdir/${pkgname}/mirisdr.rules" "${pkgdir}/etc/udev/rules.d/99-mirisdr.rules"
}