PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=libsamplerate-git
pkgver=0.2.2.r13.g22bd06e
pkgrel=1
pkgdesc="A Sample Rate Converter for audio"
arch=('i686' 'x86_64')
url="https://libsndfile.github.io/libsamplerate/"
license=('BSD')
depends=('glibc')
makedepends=('git' 'alsa-lib' 'cmake' 'libsndfile' 'opus')
checkdepends=('fftw')
provides=("libsamplerate=$pkgver" 'libsamplerate.so')
conflicts=('libsamplerate')
source=("git+https://github.com/erikd/libsamplerate.git")
sha256sums=('SKIP')


pkgver() {
  cd "libsamplerate"

  _tag=$(git tag -l --sort -v:refname | grep -E '^v?[0-9\.]+$' | head -n1)
  _rev=$(git rev-list --count $_tag..HEAD)
  _hash=$(git rev-parse --short HEAD)
  printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}

build() {
  cd "libsamplerate"

  cmake \
    -B "_build" \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX="/usr" \
    -DCMAKE_INSTALL_LIBDIR="lib" \
    -DBUILD_SHARED_LIBS=ON \
    ./
  make -C "_build"
}

check() {
  cd "libsamplerate"

  make -C "_build" test
}

package() {
  cd "libsamplerate"

  make -C "_build" DESTDIR="$pkgdir" install
  install -Dm644 {AUTHORS,NEWS,README.md,ChangeLog} -t "$pkgdir/usr/share/doc/libsamplerate"
  install -Dm644 "COPYING" -t "$pkgdir/usr/share/licenses/libsamplerate"
}