PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=libsrtp-git
pkgver=2.6.0.r59.ge53e106
pkgrel=1
pkgdesc="Library for SRTP (Secure Realtime Transport Protocol)"
arch=('i686' 'x86_64')
url="https://github.com/cisco/libsrtp"
license=('BSD-3-Clause')
depends=('glibc' 'nss')
makedepends=('git' 'libpcap' 'meson')
provides=("libsrtp=$pkgver")
conflicts=('libsrtp')
options=('staticlibs')
source=("git+https://github.com/cisco/libsrtp.git")
sha256sums=('SKIP')


pkgver() {
  cd "libsrtp"

  _tag=$(git tag -l --sort -v:refname | grep -E '^v?[0-9\.]+$' | head -n1)
  _rev=$(git rev-list --count $_tag..HEAD)
  _hash=$(git rev-parse --short HEAD)
  printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}

build() {
  cd "libsrtp"

  meson setup \
    --buildtype=plain \
    --prefix="/usr" \
    --sbindir="bin" \
    -Ddefault_library="both" \
    -Dcrypto-library="nss" \
    "_build"
  meson compile -C "_build"
}

check() {
  cd "libsrtp"

  #meson test -C "_build"
}

package() {
  cd "libsrtp"

  meson install -C "_build" --destdir "$pkgdir"
  install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/libsrtp"
}