blob: 6ceff18031a0a364d0a31f15c2edee19872ac3f6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: detiam <dehe_tian@outlook.com>
# Contributor: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Jon Nordby <jononor@gmail.com>
pkgname=libwebp0.5
pkgver=0.5.2
pkgrel=2
pkgdesc="WebP library and conversion tools"
arch=(x86_64)
url="https://developers.google.com/speed/webp/"
license=(BSD)
depends=(libpng libjpeg-turbo libtiff giflib)
makedepends=(freeglut mesa glu)
provides=(libwebp.so libwebpdecoder.so libwebpmux.so libwebpdemux.so)
optdepends=('freeglut: vwebp viewer')
source=("https://github.com/webmproject/libwebp/archive/refs/tags/v${pkgver}.tar.gz")
sha256sums=('e6555d982adc9a6397031a2545b69d0a38b5fb63b7e7a51727ec3efa93ca0575')
prepare() {
cd "$srcdir/libwebp-$pkgver"
}
build() {
cd "$srcdir/libwebp-$pkgver"
sh autogen.sh
./configure --prefix=/usr \
--enable-swap-16bit-csp \
--enable-experimental \
--enable-libwebp{mux,demux,decoder} \
--disable-static
make
}
package() {
cd "$srcdir/libwebp-$pkgver"
make install DESTDIR="$pkgdir"
# Remove unneeded files so that only the shared library remains
rm -rf "${pkgdir}"/usr/{bin,include,lib/{libwebp{mux,demux,decoder,}.{a,so},pkgconfig},share}
# HACK: system libwebp provides libwebpdemux.so.2? we don't
[[ -f /usr/lib/libwebpdemux.so.2 ]] && rm "${pkgdir}"/usr/lib/libwebpdemux.so.2
install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}
# vim:set ts=2 sw=2 et:
|