PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=libwebp2-git
pkgver=r364.g7b5fea6
pkgrel=1
pkgdesc="Successor of the WebP image format"
arch=('i686' 'x86_64')
url="https://chromium.googlesource.com/codecs/libwebp2/"
license=('Apache')
depends=('gcc-libs')
makedepends=('git' 'cmake')
provides=("libwebp2=$pkgver" 'libwebp2.so')
conflicts=('libwebp2')
source=("git+https://chromium.googlesource.com/codecs/libwebp2")
sha256sums=('SKIP')


prepare() {
  cd "libwebp2"

  sed -i 's/-Werror//' "cmake/compiler.cmake"
}

pkgver() {
  cd "libwebp2"

  _rev=$(git rev-list --count --all)
  _hash=$(git rev-parse --short HEAD)
  printf "r%s.g%s" "$_rev" "$_hash"
}

build() {
  cd "libwebp2"

  cmake \
    -B "_build" \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX="/usr" \
    -DCMAKE_INSTALL_LIBDIR="lib" \
    -DBUILD_SHARED_LIBS=ON \
    ./
  make -C "_build"
}

check() {
  cd "libwebp2"

  #make -C "_build" test
}

package() {
  cd "libwebp2"

  make -C "_build" DESTDIR="$pkgdir" install
  install -Dm644 "_build/libimageio.so" -t "$pkgdir/usr/lib"
}