blob: 0605bdce240a646baf337edbb2928d67409a5c8b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: twa022 <twa022 at gmail dot com>
# Contributor: m4sk1n <m4sk1n@o2.pl>
# Contributor: Evangelos Foutras <evangelos@foutrelis.com>
# Contributor: Xavier Devlamynck <magicrhesus@ouranos.be>
_pkgname=libxfce4ui
pkgname=${_pkgname}-devel
pkgver=4.21.0
pkgrel=1
pkgdesc="Commonly used Xfce widgets among Xfce applications (Development version)"
arch=('i686' 'x86_64' 'armv7h' 'aarch64')
url="https://docs.xfce.org/xfce/libxfce4ui/start"
license=('GPL-2.0-only')
groups=('xfce4-devel')
depends=('libxfce4util' 'gtk3' 'xfconf' 'libsm' 'startup-notification'
'libgtop' 'libepoxy' 'hicolor-icon-theme')
makedepends=('gtk-doc' 'gobject-introspection' 'vala' 'glade' 'xfce4-dev-tools' 'meson')
optdepends=('glade: Glade designer plugin')
provides=("${_pkgname}=${pkgver}")
conflicts=("${_pkgname}")
source=("https://archive.xfce.org/src/xfce/${_pkgname}/${pkgver%.*}/${_pkgname}-${pkgver}.tar.xz")
sha256sums=('dd75ff86b6ac814cf71c66004494394eeab962f5360e8e88fa724fa972b9da7b')
build() {
local meson_options=(
-D gtk-doc=true
-D x11=enabled
-D wayland=enabled
-D glade=enabled
)
arch-meson "${_pkgname}-${pkgver}" build "${meson_options[@]}"
meson compile -C build
}
package() {
meson install -C build --destdir "$pkgdir"
}
|