PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71

# Maintainer: Alex Curtis <AlexDotJDotCurtisAtProtonDotMe>

pkgbase=limo
pkgname=("${pkgbase}" "${pkgbase}-docs")
pkgver=1.1
pkgrel=2
pkgdesc='General video game mod manager with LOOT and Nexus Mods integration'
arch=('x86_64')
url="https://github.com/limo-app/${pkgbase}"
license=('GPL-3.0-only')
_depends=(
	'cpr'
	'gcc-libs'
	'glibc'
	'hicolor-icon-theme'
	'jsoncpp'
	'libarchive'
	'libloot'
	'libunrar'
	'lz4'
	'openssl'
	'pugixml'
	'qt5-base'
	'zlib'
	'zstd'
)
makedepends=(
	"${_depends[@]}"
	'cmake'
	'doxygen'
	'graphviz'
	'qt5-svg'
	'zlib'
	'zstd'
)
source=("${pkgbase}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz")
b2sums=('4a98f4632e7786fc346ff86c19ab1ef49cca640024bdbe025e3686f9b43d914d3cb730e47df8bae921a01c65981aa4bc787cb213739abae3ad42bce724b95684')

build() {
	cd "${pkgbase}-${pkgver}" || return
	cmake \
		-B build \
		-DCMAKE_BUILD_TYPE:STRING=None \
		-DCMAKE_INSTALL_PREFIX:PATH=/usr \
		-DLIMO_INSTALL_PREFIX:PATH=/usr \
		-DUSE_SYSTEM_LIBUNRAR:BOOL=ON \
		-Wno-dev
	cmake --build build
	doxygen src/lmm_Doxyfile
}

_package() {
	install -Dvm644 -t "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE
}

package_limo() {
	depends=("${_depends[@]}")
	cd "${pkgbase}-${pkgver}" || return
	DESTDIR="${pkgdir}" cmake --install build
	_package
}

package_limo-docs() {
	pkgdesc='API documentation for Limo mod manager'
	arch=('any')
	cd "${pkgbase}-${pkgver}" || return
	local _docpath="${pkgdir}/usr/share/doc/${pkgbase}"
	install -dvm755 "${_docpath}"
	mv -fvt "${_docpath}" doc/*
	_package
}