blob: e22aa6e92b73fa32fffc600ee69bf2c27b2bc507 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
# Maintainer: txtsd <aur.archlinux@ihavea.quest>
pkgname=llama.cpp-cuda-f16
_pkgname="${pkgname%-cuda-f16}"
pkgver=b4304
pkgrel=1
pkgdesc="Port of Facebook's LLaMA model in C/C++ (with NVIDIA CUDA optimizations and f16)"
arch=(x86_64 armv7h aarch64)
url='https://github.com/ggerganov/llama.cpp'
license=('MIT')
depends=(
blas-openblas
blas64-openblas
cuda
curl
gcc-libs
glibc
openmp
python
python-numpy
python-sentencepiece
)
makedepends=(
cmake
git
)
provides=(${_pkgname})
conflicts=(${_pkgname} libggml)
options=(lto)
source=(
"git+${url}#tag=${pkgver}"
"git+https://github.com/nomic-ai/kompute.git"
llama.cpp.conf
llama.cpp.service
)
sha256sums=('e371c57d56efce67ce33554bcabb3f2208bf05c81873b34303cb1948c83fba0f'
'SKIP'
'53fa70cfe40cb8a3ca432590e4f76561df0f129a31b121c9b4b34af0da7c4d87'
'0377d08a07bda056785981d3352ccd2dbc0387c4836f91fb73e6b790d836620d')
prepare() {
cd "${_pkgname}"
git submodule init
git config submodule.kompute.url "${srcdir}/kompute"
git -c protocol.file.allow=always submodule update
}
build() {
local _cmake_options=(
-B build
-S "${_pkgname}"
-DCMAKE_BUILD_TYPE=None
-DCMAKE_INSTALL_PREFIX='/usr'
-DGGML_ALL_WARNINGS=OFF
-DGGML_ALL_WARNINGS_3RD_PARTY=OFF
-DBUILD_SHARED_LIBS=ON
-DGGML_STATIC=OFF
-DGGML_LTO=ON
-DGGML_RPC=ON
-DLLAMA_CURL=ON
-DGGML_BLAS=ON
-DGGML_CUDA=ON
-DGGML_CUDA_F16=ON
-DCMAKE_CUDA_ARCHITECTURES=native
-Wno-dev
)
cmake "${_cmake_options[@]}"
cmake --build build
}
package() {
DESTDIR="${pkgdir}" cmake --install build
rm "${pkgdir}/usr/include/"ggml*
install -Dm644 "${_pkgname}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm644 "llama.cpp.conf" "${pkgdir}/etc/conf.d/llama.cpp"
install -Dm644 "llama.cpp.service" "${pkgdir}/usr/lib/systemd/system/llama.cpp.service"
}
|