blob: b6a616fd8239d38e59da96000096bbc4483615a6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
# Maintainer: dreieck (https://aur.archlinux.org/account/dreieck)
# Contributor: Lucas Rooyakkers <lucas dot rooyakkers at queensu at ca> (package `aur/loop`, which in fact was a `-git` package already.)
_pkgname=loop
pkgname="${_pkgname}-git"
pkgver=0.6.1.r140.20201117.209927c
pkgrel=1
pkgdesc="UNIX's missing loop command"
arch=('x86_64' 'i686' 'aarch64' 'armv7h')
url="https://github.com/Miserlou/Loop"
license=('MIT')
depends=(
'gcc-libs'
'glibc')
makedepends=(
'cargo'
'git'
)
provides=("loop=${pkgver}")
conflicts=('loop')
replaces=("loop=944df76")
source=("$_pkgname::git+https://github.com/Miserlou/Loop")
sha256sums=('SKIP')
prepare() {
cd "${srcdir}/${_pkgname}"
export CARGO_HOME="${srcdir}/cargo"
git log > git.log
cargo fetch -v
}
pkgver() {
cd "${srcdir}/${_pkgname}"
export CARGO_HOME="${srcdir}/cargo"
_ver="$(cargo pkgid | awk -F@ '{print $2}')"
_rev="$(git rev-list --count HEAD)"
_date="$(git log -1 --date=format:"%Y%m%d" --format="%ad")"
_hash="$(git rev-parse --short HEAD)"
if [ -z "${_rev}" ]; then
error "Version could not be determined."
return 1
else
printf '%s' "${_ver}.r${_rev}.${_date}.${_hash}"
fi
}
build() {
cd "${srcdir}/${_pkgname}"
export CARGO_HOME="${srcdir}/cargo"
if command -v rustup > /dev/null 2>&1; then
RUSTFLAGS+="-C target-cpu=native" rustup run stable \
cargo build --release
elif rustc --version | grep -q nightly; then
RUSTFLAGS+="-C target-cpu=native" \
cargo build --release
else
cargo build --release
fi
}
package() {
cd "${srcdir}/${_pkgname}"
export CARGO_HOME="${srcdir}/cargo"
install -Dvm755 "target/release/loop" "$pkgdir/usr/bin/loop"
install -Dvm644 -t "${pkgdir}/usr/share/doc/${_pkgname}" git.log README.md
install -Dvm644 -t "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE.txt
}
# vim:set ts=2 sw=2 et:
|