PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58

# Maintainer: Campbell Jones <serebit at archlinux dot org>

pkgname=magothy-git
pkgver=r256.d77b20f
pkgrel=1
pkgdesc="Hardware profiling tool"
arch=('x86_64' 'armv7h' 'aarch64')
url='https://codeberg.org/serebit/magothy'
license=('Apache-2.0')
depends=(
    'hicolor-icon-theme'
    'hwdata'
)
makedepends=(
    'cargo'
    'git'
)
optdepends=(
    'libdrm: Better AMD GPU model name reporting'
)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("$pkgname"::'git+https://codeberg.org/serebit/magothy.git')
b2sums=('SKIP')

pkgver() {
    cd "$srcdir/$pkgname"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
    cd "$srcdir/$pkgname"

    export RUSTUP_TOOLCHAIN=stable
    cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
    cd "$srcdir/$pkgname"

    export RUSTUP_TOOLCHAIN=stable
    export CARGO_TARGET_DIR=target
    cargo build --frozen --profile samply
}

package() {
    cd "$srcdir/$pkgname"

    install -Dm 0755 -t "$pkgdir/usr/bin/" "target/samply/${pkgname%-git}"
    install -Dm 0644 -t "$pkgdir/usr/share/icons/hicolor/scalable/apps/" "resources/dev.serebit.Magothy.svg"
}

check() {
    cd "$srcdir/$pkgname"

    export RUSTUP_TOOLCHAIN=stable
    cargo test --frozen
}