PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98

# Maintainer: Jesse R Codling <jclds139@gmail.com>
# Contributor: Philip Müller <philm@manjaro.org>
# Contributor: Stefano Capitani <stefano@manjaro.org>

_pkgbase=matchama-kde
_pkgname=("plasma5-themes-${_pkgbase%-kde}"{,'-wallpapers'}
          'kvantum-theme-matchama'
          'konsole-colorscheme-matchama'
          'yakuake-skin-matchama'
          'konversation-theme-matchama')
pkgname=("${_pkgname[@]/%/}")
pkgbase=${_pkgbase}
_commit=8525e052971c807d3f6797d7baf38f51c81d4b81
pkgver=r265.8525e05
pkgrel=4
arch=('any')
url="https://gitlab.com/cscs/${_pkgbase}"
license=('GPL3')
makedepends=('git')
options=('!strip')
source=("${pkgbase}::git+${url}.git#commit=${_commit}")
sha256sums=('SKIP')

pkgver() {
	cd "${pkgbase}"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
	
_install() {
	cd "${pkgbase}"
	# shellcheck disable=SC2154
	install -d "${pkgdir}"/usr/share
	cp -r "$@" "${pkgdir}"/usr/share
}

package_plasma5-themes-matchama() {
	pkgdesc="Matcha theme for KDE Plasma 5"
	depends=('plasma-workspace')
	optdepends=('papirus-icon-theme: for a more consistent and beautiful experience (recommended)'
	            'matcha-gtk-theme: for a consistent look in GTK applications'
	            'matcha-kde-wallpapers: matcha KDE wallpapers'
	            'kvantum-theme-matcha: matcha theme for Kvantum (recommended)'
	            'konsole-colorscheme-matcha: matcha theme for Konsole'
	            'yakuake-skin-matcha: matcha theme for Yakuake'
	            'konversation-theme-matcha: matcha theme for Konversation'
	            'matcha-firefox-theme: matcha theme for Firefox')
	provides=("${_pkgbase}")
	conflicts=("${_pkgbase}" 'matcha-kde')
	replaces=('matchama-kde')
	install=${pkgbase}.install

	_install plasma aurorae color-schemes
}

package_plasma5-themes-matchama-wallpapers() {
	pkgdesc="Matcha KDE wallpapers"
	provides=('plasma5-themes-matchama-wallpapers' )
	conflicts=('plasma5-themes-matchama-wallpapers')
	replaces=('matchama-kde-wallpapers')

	_install wallpapers
}

package_kvantum-theme-matchama() {
	pkgdesc="Matcha theme for Kvantum"
	depends=('kvantum')
	provides=('kvantum-theme-matchama' 'kvantum-theme-matcha')
	conflicts=('kvantum-theme-matchama')

	_install Kvantum
}

package_konsole-colorscheme-matchama() {
	pkgdesc="Matcha theme for Konsole"
	depends=('konsole')
	provides=('konsole-colorscheme-matchama')
	conflicts=('konsole-colorscheme-matchama')

	_install konsole
}

package_yakuake-skin-matchama() {
	pkgdesc="Matcha theme for Yakuake"
	depends=('yakuake')
	provides=('yakuake-skin-matchama')
	conflicts=('yakuake-skin-matchama')

	_install yakuake
}

package_konversation-theme-matchama() {
	pkgdesc="Matcha theme for Konversation"
	depends=('konversation')
	provides=('konversation-theme-matchama')
	conflicts=('konversation-theme-matchama')

	_install konversation
}