PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: Murmele <martin.marmsoler AT gmail DOT com>

pkgname=mdflib-git
pkgver=r83.g3215f84
pkgrel=1
pkgdesc="The MDF Library implements an interface against ASAM Measurement Data Files (MDF)"
arch=('i686' 'x86_64')
url="https://ihedvall.github.io/mdflib/"
license=('MIT')
depends=('expat' 'zlib')
makedepends=('git' 'cmake')  # gcc-fortran
provides=('mdflib')
conflicts=('mdflib')
options=('staticlibs')
source=("git+https://github.com/ihedvall/mdflib.git")
sha256sums=('SKIP')


pkgver() {
  cd "mdflib"

  _rev=$(git rev-list --count --all)
  _hash=$(git rev-parse --short HEAD)
  printf "r%s.g%s" "$_rev" "$_hash"
}

build() {
  cd "mdflib"

  cmake \
    -B "build" \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX="/usr" \
    -DCMAKE_INSTALL_LIBDIR="lib" \
    -DMDF_BUILD_DOC=OFF \
    -DMDF_BUILD_TEST=OFF \
    -DMDF_BUILD_TOOL=OFF \
    ./
  make -C "build"
}

package() {
  cd "mdflib"

  make -C "build" DESTDIR="$pkgdir" install
  install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/mdflib"
}