blob: 70487060186bc62a0bf393f347e1c56531c683f8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Maintainer: Chris Lane <aur at chrislane dot com>
# Contributor: Stephanie Wilde-Hobbs <hi@stephanie.is>
pkgname=megacmd
pkgver=1.7.0
pkgrel=4
pkgdesc="MEGA Command Line Interactive and Scriptable Application"
url="https://github.com/meganz/MEGAcmd"
arch=('x86_64')
license=('custom')
depends=('crypto++' 'sqlite' 'c-ares' 'ffmpeg' 'freeimage'
'libsodium' 'libmediainfo' 'pcre' 'libuv')
makedepends=('git' 'autoconf')
_sdkhash="e448c09e73a4496329f46e538f1f20143b618ed1"
source=(
"${pkgname}-${pkgver}-${pkgrel}.tar.gz::https://github.com/meganz/MEGAcmd/archive/${pkgver}_ArchLinux.tar.gz"
"mega-sdk-${_sdkhash}.tar.gz::https://github.com/meganz/sdk/archive/${_sdkhash}.tar.gz"
"fix-ffmpeg-compile.patch")
sha512sums=('c1b058ef665cdff4c623a9b63643f9daf3fb0cd3875acdf96e3e01dfb5e8109b0ac39c1769755f2e8f8a6f82ecd8b300902665e2ac168363dd8dc9ca94d415b5'
'9620bbc50db1ee4dd329f91cd5b34f7f8f9443f3d83258b76077c5cab7157fd2d31fc4e8ef18fbc07053d66eda0c9c722cfa9eb86c710c0b112a37da533b4bb5'
'e843e40f72c69b05669478f13b092c115e37505692df1e781724f4466fc56b2339aa44470dbaec16c1cb06816fc779c08f57037cf8bfcf6d8aa966e00c3bf013')
prepare() {
cd "MEGAcmd-${pkgver}_ArchLinux"
rm -r sdk
ln -sf "../sdk-${_sdkhash}" sdk
cd sdk
patch -Np1 < "${srcdir}"/fix-ffmpeg-compile.patch
}
build() {
cd "MEGAcmd-${pkgver}_ArchLinux"
./autogen.sh
./configure --prefix=/usr
make
}
package() {
cd "MEGAcmd-${pkgver}_ArchLinux"
make DESTDIR=${pkgdir} install
# change completions location
rm -rf ${pkgdir}/usr/etc/
install -Dm644 src/client/megacmd_completion.sh ${pkgdir}/usr/share/bash-completion/completions/${pkgname}
for completion_cmd in ${pkgdir}/usr/bin/mega*;
do
completion_cmd=$(basename "$completion_cmd")
ln -s "${pkgname}" "${pkgdir}/usr/share/bash-completion/completions/$completion_cmd"
done
install -Dm644 LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
}
# vim:set ts=2 sw=2 et:
|