PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72

# Maintainer: Luna Jernberg <droidbittin@gmail.com>
# Maintainer: Jonas Schwartz <jonas@josc.io>
# Maintainer: Vlad <ejiek at mail.ru>
# Maintainer: Solomon Choina<shlomochoina@gmail.com>
# Maintainer: Christopher Snowhill <kode54@gmail.com>
# Contributor: Caleb Maclennan <caleb@alerque.com>
# Contributor: intrnl

_channel=dev
_pkgname=microsoft-edge-dev
pkgname=microsoft-edge-dev-bin
_pkgshortname=msedge-dev
pkgver=133.0.3014.0
pkgrel=1
_uprel=1
pkgdesc="A browser that combines a minimal design with sophisticated technology to make the web faster, safer, and easier"
arch=(x86_64)
url="https://www.microsoftedgeinsider.com/en-us/download"
license=(custom)
provides=("microsoft-edge=$pkgver")
conflicts=(microsoft-edge)
depends=(gtk3 libcups nss alsa-lib libxtst libdrm mesa)
makedepends=(imagemagick)
optdepends=('gnome-keyring: for storing passwords in GNOME keyring'
            'gtk3: for printing'
            'kdialog: for file dialogs in KDE'
            'kwallet: for storing passwords in KWallet'
            'libpipewire: WebRTC desktop sharing under Wayland'
            'libunity: for download progress on KDE'
            'ttf-liberation: fix fonts for some PDFs - CRBug #369991'
            'xdg-utils')
options=(!strip !zipman)
source=("https://packages.microsoft.com/repos/edge/pool/main/m/$_pkgname/${_pkgname}_$pkgver-${_uprel}_amd64.deb"
        "$_pkgname.sh"
        "Microsoft Standard Application License Terms - Standalone (free) Use Terms.pdf")
sha256sums=('65bd291d453d6aa53e509852b89e2cb60980c483fedf6eedd3a77c43edda42cf'
            '285afe53b2cd617ae7f4930a1d0befe12a97ae31c30cfad74e97bf695c6f6a8a'
            'edf2ed596eb068f168287fc76aa713ad5e0afb59f0a0a47a4f29c0c124ade15e')

package() {
	bsdtar -xf data.tar.xz -C "$pkgdir/"

	# suid sandbox
	chmod 4755 "$pkgdir/opt/microsoft/$_pkgshortname/msedge-sandbox"

	# 256 and 24 are proper colored icons
	for res in 128 64 48 32; do
		magick "$pkgdir/opt/microsoft/$_pkgshortname/product_logo_256_dev.png" \
			-resize "${res}x${res}" \
			"$pkgdir/opt/microsoft/$_pkgshortname/product_logo_${res}_dev.png"
	done
	for res in 22 16; do
		magick "$pkgdir/opt/microsoft/$_pkgshortname/product_logo_24_dev.png" \
			-resize "${res}x${res}" \
			"$pkgdir/opt/microsoft/$_pkgshortname/product_logo_${res}_dev.png"
	done

	# copy icons where FHS expects them
	for res in 16 22 24 32 48 64 128 256; do
		install -Dm644 "$pkgdir/opt/microsoft/$_pkgshortname/product_logo_${res}_dev.png" \
			"$pkgdir/usr/share/icons/hicolor/${res}x${res}/apps/$_pkgname.png"
	done

	# User flag aware launcher
	install -Dm0755 microsoft-edge-dev.sh "$pkgdir/usr/bin/$_pkgname"

	install -Dm0644 'Microsoft Standard Application License Terms - Standalone (free) Use Terms.pdf' "$pkgdir/usr/share/licenses/$pkgname/LICENSE.pdf"
	rm -r "$pkgdir/etc/cron.daily/" "$pkgdir/opt/microsoft/$_pkgshortname/cron/"
	rm "$pkgdir/opt/microsoft/$_pkgshortname/"product_logo_*.png
}