blob: eb14e6438d88446779048acda7b7b6d595c1cc33 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: drakkan <nicola.murino at gmail dot com>
pkgname=mingw-w64-gstreamer
pkgver=1.24.5
pkgrel=1
pkgdesc="GStreamer Multimedia Framework (mingw-w64)"
arch=(any)
url="http://gstreamer.freedesktop.org/"
license=('LGPL')
makedepends=('mingw-w64-meson' 'glib2-devel')
depends=('mingw-w64-glib2' 'mingw-w64-libxml2')
options=('!strip' '!buildflags' 'staticlibs')
source=(${url}src/gstreamer/gstreamer-${pkgver}.tar.xz)
sha256sums=('2bdef209252bf146351843134b797db6b6e7adb4c00d82e83bd5abe608253a7b')
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
build() {
cd "${srcdir}/gstreamer-${pkgver}"
for _arch in $_architectures; do
mkdir -p "build-${_arch}" && pushd build-${_arch}
${_arch}-meson \
-D strip=true \
-D examples=disabled \
-D doc=disabled \
-D package-name="GStreamer (Arch Linux)" \
-D package-origin="http://www.archlinux.org/" ..
ninja
popd
done
}
package() {
cd "${srcdir}/gstreamer-${pkgver}"
for _arch in ${_architectures}; do
DESTDIR="${pkgdir}" ninja -C "${srcdir}/gstreamer-${pkgver}/build-${_arch}" install
done
}
# vim: ts=2 sw=2 et:
|