blob: 42a48ffe0a257835062f7bdff6c85866e9aaa19a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Stefan Wimmer <info@stefanwimmer128.xyz>
# Contributor: Daniel Menelkir <menelkir@gmail.com>
# Contributor: Alad Wenter <alad@archlinux.org>
# Contributor: Thorsten Töpper <atsutane-tu@freethoughts.de>
# Contributor: Daniel Hommel <dhommel@gmail.com>
pkgname=mksh
pkgver=59c
pkgrel=1
pkgdesc='MirBSD Korn Shell'
url='https://www.mirbsd.org/mksh.htm'
license=('custom')
arch=('x86_64')
depends=('glibc')
makedepends=('git')
checkdepends=('ed')
install=mksh.install
source=("$pkgname::git+https://github.com/MirBSD/mksh.git#tag=mksh-R$pkgver"
'no-ctty.patch')
sha256sums=('SKIP'
'ded3a8a3628fd5a1c7e2eed62dfe35114aafe580077a4f6f766729714c7525b5')
check() {
cd "$pkgname"
PERL=/usr/bin/perl ./test.sh
}
prepare() {
cd "$pkgname"
sed -i 's/fgrep/grep -F/g' check.t
if ! tty > /dev/null; then
patch -Nsp1 -i "$srcdir/no-ctty.patch"
fi
}
build() {
cd "$pkgname"
sh Build.sh -r
}
package() {
cd "$pkgname"
install -D -m 755 mksh "$pkgdir/usr/bin/mksh"
install -D -m 644 mksh.1 "$pkgdir/usr/share/man/man1/mksh.1"
install -D -m 644 dot.mkshrc "$pkgdir/etc/skel/.mkshrc"
mkdir -p "$pkgdir/usr/share/licenses/mksh/"
sed -n '/Copyright/,/\*\//p' main.c > "$pkgdir/usr/share/licenses/mksh/LICENSE"
}
|