blob: b79ca85c71e6b27d96a9dde5b47631732dfe1e6c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
# Contributor: matthias.lisin
pkgname="mockery"
pkgver=2.52.1
pkgrel=1
pkgdesc="A mock code autogenerator for Go"
arch=('aarch64' 'x86_64')
url="https://vektra.github.io/mockery"
_url="https://github.com/vektra/${pkgname}"
license=('BSD-3-Clause')
depends=('glibc')
makedepends=('go')
provides=('golang-mockery')
conflicts=('golang-mockery')
replaces=('golang-mockery')
_pkgsrc="${pkgname}-${pkgver}"
source=("${_pkgsrc}.tar.gz::${_url}/archive/refs/tags/v${pkgver}.tar.gz")
sha256sums=('1bc8127b4df281d692c58ca3d10167fad759ca5796e88d4e2c84aed02aed18cd')
prepare() {
cd "${srcdir}/${_pkgsrc}"
mkdir -p "build" "completions"
}
build() {
cd "${srcdir}/${_pkgsrc}"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
go build -v -o "build/${pkgname}" -ldflags "\
-X ${_url#https://}/v2/pkg/logging.SemVer=${pkgver}" \
.
# --config=/dev/null to avoid reading .mockery.yaml
for _sh in bash fish powershell zsh; do
./"build/${pkgname}" --config='/dev/null' completion "${_sh}" > "completions/${pkgname}.${_sh}"
done
}
# check() {
# cd "${srcdir}/${_pkgsrc}"
# go test ./...
# }
package() {
cd "${srcdir}/${_pkgsrc}"
install -vDm755 "build/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
install -vDm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
install -vDm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
cd "completions"
install -vDm644 "${pkgname}.bash" "${pkgdir}/usr/share/bash-completion/completions/${pkgname}"
install -vDm644 "${pkgname}.fish" "${pkgdir}/usr/share/fish/vendor_completions.d/${pkgname}.fish"
install -vDm644 "${pkgname}.powershell" "${pkgdir}/usr/share/powershell/Completions/${pkgname}.ps1"
install -vDm644 "${pkgname}.zsh" "${pkgdir}/usr/share/zsh/site-functions/_${pkgname}"
}
|