PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Maintainer: XenHat <me at xenh.at>
# Contributors: SoftwareRat <jaguar5018@gmail.com>, Michael Herzberg

pkgname=moonlight-qt-git
pkgver=6.1.0.r16.g6ce0261
pkgrel=2
pkgdesc='GameStream client for PCs (Windows, Mac, and Linux) (master branch)'
arch=('aarch64' 'x86_64')
license=('GPL-3.0-or-later')
url='https://github.com/moonlight-stream/moonlight-qt'
depends=('qt6-base' 'qt6-declarative' 'qt6-svg' 'ffmpeg' 'sdl2_ttf')
makedepends=('git')
optdepends=(
	'libva-intel-driver: hardware-acelerated decoding for Intel'
	'libva-mesa-driver: hardware-acelerated decoding for AMD/others'
	'libva-nvidia-driver: hardware-acelerated decoding for NVIDIA with NVDEC via VA-API'
)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=($pkgname::"git+https://github.com/moonlight-stream/${pkgname%-git}.git")

md5sums=('SKIP')

pkgver() {
	cd "$pkgname"
	git describe --long --tags --abbrev=7 --exclude='*[a-zA-Z][a-zA-Z]*' |
		sed -E 's/^[^0-9]*//;s/([^-]*-g)/r\1/;s/-/./g'
}

prepare() {
	cd "$pkgname"
	git submodule update --init --recursive
	if [[ -f *.patch ]]; then
		for p in ../*.patch; do
			patch -Np1 -i "$p"
		done
	fi
	qmake6 PREFIX="$pkgdir/usr" moonlight-qt.pro
}

build() {
	cd "$pkgname"
	make
}

package() {
	cd "$pkgname"
	make install
}