blob: 654aac7535f6ffb4edcdb5caa39c32aa6ba77c59 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: "Amhairghin" Oscar Garcia Amor (https://ogarcia.me)
# Contributor: Fredrik Strandin <fredrik@strandin.name>
_commit='298ed9b8ed396bdec0b046f88cd2d7a29db2a6ce'
pkgname=mop
pkgver=2024.12.30
pkgrel=1
pkgdesc='Stock market tracker for hackers'
arch=('i686' 'x86_64' 'armv6h' 'armv7h' 'aarch64')
url='https://github.com/mop-tracker/mop'
license=('MIT')
depends=('glibc')
makedepends=('git' 'go')
conflicts=('mop-git')
options=('!emptydirs' '!lto')
source=("${pkgname}-${pkgver}.tar.gz"::"https://github.com/mop-tracker/${pkgname}/archive/${_commit}.tar.gz")
b2sums=('3fb0e7bfe6854b9140afbf3e108f8a22de8b0310a836ddbd9563995ffa993b83aa6f7cd51f05de34508e189dfaa4a89cd48ce92dc9f61923a5eadc4304a3c303')
build() {
cd "${pkgname}-${_commit}"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"
_LDFLAGS="-X main.version=${pkgver} -X main.branch=master -X main.commit=${_commit} -linkmode=external"
go build -o mop -ldflags="${_LDFLAGS}" "./cmd/..."
}
package() {
# binary
install -D -m755 "${srcdir}/${pkgname}-${_commit}/mop" \
"${pkgdir}/usr/bin/mop"
# docs
install -D -m644 "${srcdir}/${pkgname}-${_commit}/README.md" \
"${pkgdir}/usr/share/doc/${pkgname}/README.md"
# license
install -D -m644 "${srcdir}/${pkgname}-${_commit}/LICENSE" \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|