blob: d2ddd1c8e76ea24195ebd4ad46b0de86be93ce67 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
pkgname="nak"
pkgver=0.13.2
pkgrel=1
pkgdesc="A command line tool for doing all things nostr"
arch=('aarch64' 'armv7h' 'riscv64' 'x86_64')
url="https://github.com/fiatjaf/${pkgname}"
license=('Unlicense')
depends=('glibc')
makedepends=('go')
_pkgsrc="${pkgname}-${pkgver}"
source=("${_pkgsrc}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz")
b2sums=('ceeaf5326c16f8c7bdfd53d7b4ab054d6eb1189b63520e65e83f8f9ddff5a08e918d5b0d2457ee37b9d99a71a4ddee886fab594efea8e09541e52b8dc3ca3eb7')
prepare() {
cd "${srcdir}/${_pkgsrc}"
mkdir -p "build"
}
build() {
cd "${srcdir}/${_pkgsrc}"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
go build -o "build/${pkgname}" .
}
# check() {
# cd "${srcdir}/${_pkgsrc}"
# go test ./...
# }
package() {
cd "${srcdir}/${_pkgsrc}"
install -vDm755 "build/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
install -vDm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
install -vDm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|