blob: 0610a340d18fba6e45e1e56fa4713cc6729c80ab (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
|
# Maintainer: tarball <bootctl@gmail.com>
pkgbase=narrowlink
pkgname=(
"$pkgbase"
"$pkgbase-gateway"
"$pkgbase-agent"
"$pkgbase-token-generator"
)
pkgver=0.2.6
pkgrel=1
pkgdesc='Securely connect devices and services, even in restricted networks'
url='https://narrowlink.com'
arch=(i686 x86_64 armv7h aarch64)
makedepends=(cargo mold)
depends=(glibc gcc-libs)
source=(
"$pkgbase-$pkgver.tar.gz::https://github.com/narrowlink/narrowlink/archive/refs/tags/$pkgver.tar.gz"
"$pkgbase.service.in"
)
sha256sums=('6682e742431fa3496cbfd550039c6fe46c87fbce6a74d0d2c227cae38e8e2dd3'
'b60d1792b67d877064fd8164177f2d5dca7e220e42e0679f53216a4ec8a6f46d')
prepare() {
cd "$pkgbase-$pkgver"
export RUSTUP_TOOLCHAIN=stable
cargo fetch --target "$CARCH-unknown-linux-gnu"
}
build() {
cd "$pkgbase-$pkgver"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
# credit to Sergey A. https://aur.archlinux.org/packages/aichat#comment-959940
export RUSTFLAGS="${RUSTFLAGS:-} -C link-arg=-fuse-ld=mold"
cargo build --frozen --release --all-features
}
check() {
cd "$pkgbase-$pkgver"
export RUSTUP_TOOLCHAIN=stable
export RUSTFLAGS="${RUSTFLAGS:-} -C link-arg=-fuse-ld=mold"
cargo test --frozen --all-features
}
package_narrowlink() {
license=(MPL-2.0)
backup=("etc/$pkgbase/client.yaml")
cd "$pkgbase-$pkgver"
install -Dm600 client/sample_client.yaml "$pkgdir/etc/$pkgbase/client.yaml"
install -Dm755 "target/release/$pkgname" "$pkgdir/usr/bin/$pkgname"
}
package_narrowlink-gateway() {
license=(AGPL-3.0-only)
backup=("etc/$pkgbase/gateway.yaml")
sed "s/__NAME__/gateway/g" <"$pkgbase.service.in" >"$pkgname.service"
install -Dm644 "$pkgname.service" "$pkgdir/usr/lib/systemd/system/$pkgname.service"
cd "$pkgbase-$pkgver"
install -Dm600 gateway/sample_gateway.yaml "$pkgdir/etc/$pkgbase/gateway.yaml"
install -Dm755 "target/release/$pkgname" "$pkgdir/usr/bin/$pkgname"
}
package_narrowlink-agent() {
license=(MPL-2.0)
backup=("etc/$pkgbase/agent.yaml")
sed "s/__NAME__/agent/g" <"$pkgbase.service.in" >"$pkgname.service"
install -Dm644 "$pkgname.service" "$pkgdir/usr/lib/systemd/system/$pkgname.service"
cd "$pkgbase-$pkgver"
install -Dm600 agent/sample_agent.yaml "$pkgdir/etc/$pkgbase/agent.yaml"
install -Dm755 "target/release/$pkgname" "$pkgdir/usr/bin/$pkgname"
}
package_narrowlink-token-generator() {
license=(MPL-2.0)
backup=("etc/$pkgbase/token-generator.yaml")
cd "$pkgbase-$pkgver"
install -Dm600 token-generator/sample_token-generator.yaml "$pkgdir/etc/$pkgbase/token-generator.yaml"
install -Dm755 "target/release/$pkgname" "$pkgdir/usr/bin/$pkgname"
}
|