PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30

# Maintainer: Martin Rys <https://rys.rs/contact> | Toss a coin on https://rys.rs/donate
# Previous Maintainer: Jochen Jägers (JochenJ) <aur@diezonks.de>
# Contributor: Malte Rabenseifner <mail@malte-rabenseifner.de>
# Contributor: Patrick Burroughs (Celti) <celti@celti.name>

pkgname=networkmanager-libreswan
pkgver=1.2.24
pkgrel=1
pkgdesc="NetworkManager IPSec VPN plugin for Libreswan"
arch=('i686' 'x86_64')
license=('GPL-2.0-or-later')
url='https://networkmanager.dev/docs/vpn/'
depends=('libsecret' 'libreswan' 'libnl' 'libnm' 'gtk3' 'libnma')
makedepends=('glib2-devel' 'intltool' 'python' 'gettext')
source=("https://download.gnome.org/sources/NetworkManager-libreswan/${pkgver::3}/NetworkManager-libreswan-${pkgver}.tar.xz")
sha256sums=('3d491c726339f0cafd9a35e4e037add58617f3d5d683b75a545ddc6fbe382457')

build() {
	cd "NetworkManager-libreswan-${pkgver}"
	./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
		--libexecdir=/usr/lib/NetworkManager \
		--enable-more-warnings=yes \
		--disable-static
	make
}

package() {
	cd "NetworkManager-libreswan-${pkgver}"
	make DESTDIR="${pkgdir}" install
}