blob: 786e27e00cc0c66cbb45ac7e9c7b5309ef9bfb62 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: <reg-archlinux AT klein DOT tuxli DOT ch>
# Contributor: Davide Depau <davide@depau.eu>
# Contributor: carstene1ns <arch carsten-teibes de> - http://git.io/ctPKG
# Contributor: Eric Bélanger <eric@archlinux.org>
pkgname=neverball-git
pkgver=1.6.0.r433.g96c23af4
pkgrel=1
pkgdesc="3D game similar to Super Monkey Ball or Marble Madness"
arch=('x86_64')
url="https://neverball.org/"
license=('GPL')
depends=('sdl2_ttf' 'libgl' 'libpng' 'libjpeg' 'libvorbis' 'physfs' \
'hicolor-icon-theme' 'xdg-utils')
makedepends=('mesa' 'git')
source=("${pkgname}::git+https://github.com/Neverball/neverball.git")
sha256sums=('SKIP')
pkgver() {
cd "$pkgname"
# cutting off 'foo-' prefix that presents in the git tag
git describe --long | sed 's/^foo-//;s/\([^-]*-g\)/r\1/;s/-/./g' | sed 's/neverball[.]//g'
}
build() {
cd ${pkgname}
make DATADIR=/usr/share/neverball LOCALEDIR=/usr/share/locale \
CPPFLAGS="$CPPFLAGS -DNDEBUG" CFLAGS="$CFLAGS"
}
package(){
cd ${pkgname}
install -d "${pkgdir}/usr/bin"
install -d "${pkgdir}"/usr/share/{neverball,locale,applications,doc/neverball}
install -d "${pkgdir}"/usr/share/man/man{1,6}
install -m755 neverball neverputt mapc "${pkgdir}/usr/bin"
cp -r locale/* "${pkgdir}/usr/share/locale/"
cp -r data/* "${pkgdir}/usr/share/neverball/"
cp -r doc/* "${pkgdir}/usr/share/doc/neverball/"
install -m644 dist/*.desktop "${pkgdir}/usr/share/applications/"
install -m644 dist/mapc.1 "${pkgdir}/usr/share/man/man1"
install -m644 dist/{neverball.6,neverputt.6} "${pkgdir}/usr/share/man/man6"
for i in 16 24 32 48 64 128 256 512; do
install -D -m644 dist/neverball_$i.png "${pkgdir}/usr/share/icons/hicolor/${i}x$i/apps/neverball.png"
install -D -m644 dist/neverputt_$i.png "${pkgdir}/usr/share/icons/hicolor/${i}x$i/apps/neverputt.png"
done
chmod -R u=rwX,go=rX "${pkgdir}/usr/share/neverball"
}
|