blob: dc5a3cc02fb5d3bf91f68a68cdf70b6345103259 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: devome <evinedeng@hotmail.com>
pkgname="nginx-ui"
pkgver=2.0.0_rc.5
_pkgver=${pkgver//_/-}
pkgrel=1
pkgdesc="Yet another WebUI for Nginx"
arch=('i686' 'pentium4' 'x86_64' 'arm' 'armv7h' 'armv6h' 'aarch64' 'riscv64')
url="https://github.com/0xJacky/${pkgname}"
backup=("etc/${pkgname}/config.ini")
license=("AGPL-3.0-or-later")
depends=("nginx")
makedepends=("pnpm" "go")
source=("${pkgname}-${_pkgver}.tar.gz::${url}/archive/refs/tags/v${_pkgver}.tar.gz")
sha256sums=('927e31e5eccef71e4e4efb81c55b16f8197b9dfe5ad064b35638db4fc88df9ad')
build() {
export CGO_CFLAGS="${CFLAGS}"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
cd "${pkgname}-${_pkgver}"
pnpm --prefix app install
pnpm --prefix app build
local ldflags="
-s -w \
-extldflags '${LDFLAGS}' \
-X 'github.com/0xJacky/Nginx-UI/settings.buildTime=$(date +%s)'
"
go build \
-trimpath \
-tags jsoniter \
-ldflags="${ldflags}" \
-o "${pkgname}" \
./main.go
sed -E \
-e "s|^(ExecStart=).+|\1/usr/bin/${pkgname} --config /etc/${pkgname}/config.ini|g" \
-e "s|^(Documentation=).+|\1https://nginxui.com|g" \
-i "${pkgname}.service"
}
package() {
cd "${pkgname}-${_pkgver}"
install -Dm755 "${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
install -Dm644 "${pkgname}.service" "${pkgdir}/usr/lib/systemd/system/${pkgname}.service"
install -Dm644 app.example.ini "${pkgdir}/etc/${pkgname}/config.ini"
install -Dm644 *.md -t "${pkgdir}/usr/share/doc/${pkgname}"
}
|