PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

# Maintainer: Atle Solbakken <atle@goliathdns.no>

pkgname=ngtcp2-git
pkgver=r4927.8ae7650c
pkgrel=1
pkgdesc="An effort to implement IETF QUIC protocol"
arch=('x86_64')
url="https://github.com/ngtcp2/ngtcp2"
license=('MIT')
depends=('gnutls')
optdepends=('quictls-openssl')
makedepends=('git')
checkdepends=('cunit')
provides=('ngtcp2' 'libngtcp2.so')
conflicts=('ngtcp2' 'libngtcp2' 'libngtcp2-git')
source=('git+https://github.com/ngtcp2/ngtcp2')
md5sums=('SKIP')

prepare() {
	cd ngtcp2

	git submodule update --init --depth 1
}

pkgver() {
	cd ngtcp2

	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
	cd ngtcp2

	autoreconf -fisv

	WITH="--with-gnutls"
	if [ pacman -Q quictls-openssl > /dev/null 2>&1 ]; then
		WITH="$WITH --with-openssl"
	fi

	./configure \
      --prefix=/usr $WITH

	make
}

check() {
	cd ngtcp2

	make -k check
}

package() {
	cd ngtcp2

	make DESTDIR="$pkgdir" install
}