PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Contributor: Whemoon Jang <palindrom615@gmail.com>
# Contributor: Bumsik Kim <k.bumsik@gmail.com>
# Contributor: Hodong Kim <https://gitlab.com/hodong>

pkgname=nimf
pkgver=1.3.7
pkgrel=1
epoch=1
pkgdesc='a lightweight, fast and extensible input method framework'
arch=(x86_64)
url="https://github.com/hamonikr/$pkgname"
license=(LGPL-3.0-only)
depends=(gtk3
         libappindicator-gtk3
         libxkbcommon
         libxklavier
         qt5-base
         wayland
         wayland-protocols)
makedepends=(anthy
             glib2-devel
             gtk-doc
             gtk2
             intltool
             libayatana-appindicator
             libhangul-git
             librime
             m17n-db
             m17n-lib
             librsvg)
optdepends=('brise: Rime schema repository'
            'noto-fonts-cjk: Google Noto CJK fonts')
_archive="$pkgname-$pkgver"
source=("$url/archive/v$pkgver/$_archive.tar.gz")
sha256sums=('17fbe0628d1dce17abb5413e370237908fd668533ddc398bf7996d9a8fda5d21')

prepare() {
	cd "$_archive"
	./autogen.sh
}

build() {
	cd "$_archive"
	./configure --prefix /usr
}

package() {
	cd "$_archive"
	make DESTDIR="$pkgdir/" install
}