blob: 1140a78811b17d4084ca3d15e27dae9ab7413ab4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# Maintainer: Maël Kerbiriou <m431.kerbiriou@gmail.com>
pkgname=nix-zsh-completions-git
_pkgname=nix-zsh-completions
pkgver=0.4.4.r13.g6a1bfc0
pkgrel=1
pkgdesc="ZSH Completions for Nix"
arch=(any)
url="https://github.com/nix-community/nix-zsh-completions"
license=(BSD)
depends=(zsh)
makedepends=(git)
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=("${_pkgname}::git+https://github.com/nix-community/nix-zsh-completions.git")
sha256sums=('SKIP')
pkgver() {
cd "${srcdir}/${_pkgname}"
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
package() {
cd "${srcdir}/${_pkgname}"
# Main completion functions (standalone, automatically loaded by compinit)
install -m0644 -Dt "${pkgdir}/usr/share/zsh/site-functions" _*
# OMZ plugin for extra functionalities (can be sourced from zshrc)
install -m0644 -Dt "${pkgdir}/usr/share/zsh/plugins/${_pkgname}" "${_pkgname}.plugin.zsh"
# Misc.
install -m0644 -Dt "${pkgdir}/usr/share/doc/${_pkgname}" README.md
install -m0644 -Dt "${pkgdir}/usr/share/licenses/${_pkgname}" LICENSE
}
# vim: set noet ff=unix:
|