blob: 5d8d58c4f0c1ac5edd89ef83f7274a8ef6172d9f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
# Previous maintainer: Jesin <Jesin00@gmail.com>
# Contributor: Eduardo Sánchez Muñoz
pkgname=nlohmann-json-git
pkgver=3.11.3.r14.g960b763ec
pkgrel=1
pkgdesc="JSON for Modern C++"
arch=('any')
url="https://github.com/nlohmann/json"
license=('MIT')
makedepends=('git' 'cmake')
provides=("nlohmann-json=$pkgver")
conflicts=('nlohmann-json')
source=("git+https://github.com/nlohmann/json.git")
sha256sums=('SKIP')
pkgver() {
cd "json"
_tag=$(git tag -l --sort -v:refname | grep -E '^v?[0-9\.]+$' | head -n1)
_rev=$(git rev-list --count $_tag..HEAD)
_hash=$(git rev-parse --short HEAD)
printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}
build() {
cd "json"
cmake \
-B "_build" \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX="/usr" \
-DCMAKE_INSTALL_LIBDIR="lib" \
-DJSON_BuildTests=OFF \
./
cmake --build "_build"
}
check() {
cd "json"
#cmake --build "_build" --target test
}
package() {
cd "json"
DESTDIR="$pkgdir" cmake --install "_build"
install -Dm644 "README.md" -t "$pkgdir/usr/share/doc/nlohmann-json"
install -Dm644 "LICENSE.MIT" -t "$pkgdir/usr/share/licenses/nlohmann-json"
}
|