PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: f4iey <f4iey@f4iey.fr>	

pkgname=not1mm-git
pkgver=r1447.5cad407
pkgrel=1
pkgdesc="Not1MM != N1MM, An amateur radio contest logger for Linux."
arch=('any')
license=('GPL3')
url="https://github.com/mbridak/not1mm"
makedepends=(git python-build python-installer python-wheel)
depends=('python' 'python-pyqt5' 'python-pyqt6' 'python-requests' 'python-dicttoxml' 'python-xmltodict' 'python-psutil'
	 'python-sounddevice' 'python-soundfile' 'python-numpy' 'python-notctyparser' 'python-pyserial' 'python-appdata'
	 'python-gobject' 'python-thefuzz' 'python-levenshtein' 'gtk4' 'hamradio-menus')
optdepends=(hamlib flrig)
provides=(not1mm)
conflicts=(not1mm)
source=($pkgname::"git+$url.git")
sha256sums=('SKIP')

prepare(){
    git -C "$srcdir/$pkgname" clean -dfx
}

 pkgver() {
    cd "$srcdir/$pkgname"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  cd $srcdir/$pkgname
  python -m build --wheel --no-isolation
}

package() {
  cd $srcdir/$pkgname
  python -m installer --destdir="$pkgdir" dist/*.whl
  # Desktop icon
  install -Dm755 "not1mm/data/k6gte-not1mm.desktop" "$pkgdir/usr/share/applications/k6gte-not1mm.desktop"
  install -Dm755 "not1mm/data/k6gte.not1mm.svg" "$pkgdir/usr/share/pixmaps/k6gte-not1mm.svg"

}