PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Maintainer: Max Luebke <maxluebke(at)gmail.com>
# Contributor: Luis Martinez <luis dot martinez at disroot dot org>
# Contributor: bitwave <aur [aT] oomlu {d.0t} de>
# Contributor: yochananmarqos

pkgname=notepadnext
pkgver=0.11
pkgrel=1
pkgdesc="Cross-platform reimplementation of Notepad++"
arch=('x86_64')
url="https://github.com/dail8859/NotepadNext"
license=('GPL-3.0-only')
depends=('gcc-libs' 'glibc' 'libxcb' 'qt6-5compat' 'hicolor-icon-theme' 'qt6-base')
makedepends=('git' 'qt6-tools')
source=("$pkgname::git+$url#tag=v$pkgver"
    'git+https://github.com/alex-spataru/QSimpleUpdater'
    'git+https://github.com/githubuser0xFFFF/Qt-Advanced-Docking-System'
    'git+https://github.com/editorconfig/editorconfig-core-qt'
    'git+https://github.com/itay-grudev/SingleApplication'
    'git+https://gitlab.freedesktop.org/uchardet/uchardet.git/')
sha256sums=('5e0062af581a0006ee3eece84ef71bef7e94de4e3b1c77539815ca8f2ae35622'
    'SKIP'
    'SKIP'
    'SKIP'
    'SKIP'
    'SKIP')

prepare() {
    cd "${srcdir}/${pkgname}"
    git submodule init
    git config submodule.src/QSimpleUpdater.url "$srcdir/QSimpleUpdater"
    git config submodule.src/src/ads.url "$srcdir/Qt-Advanced-Docking-System"
    git config submodule.src/editorconfig-core-qt.url "$srcdir/editorconfig-core-qt"
    git config submodule.src/singleapplication.url "$srcdir/SingleApplication"
    git config submodule.src/uchardet.url "$srcdir/uchardet"
    git -c protocol.file.allow=always submodule update
    mkdir -p build
}

build() {
    cd "${srcdir}/${pkgname}/build"
    qmake6 ../src/NotepadNext.pro
    make
}

package() {
    cd "${srcdir}/${pkgname}/build"
    make INSTALL_ROOT="${pkgdir}" install
}