PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=nuspell-git
pkgver=5.1.2.r2.g1ae818e
pkgrel=1
pkgdesc="Fast and safe spellchecking C++ library"
arch=('i686' 'x86_64')
url="https://nuspell.github.io/"
license=('GPL3' 'LGPL3')
depends=('glibc' 'boost-libs' 'icu')
makedepends=('git' 'cmake' 'boost' 'ruby-ronn')
provides=("nuspell=$pkgver")
conflicts=('nuspell')
source=("git+https://github.com/nuspell/nuspell.git")
sha256sums=('SKIP')


pkgver() {
  cd "nuspell"

  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "nuspell"

  cmake \
    -B "_build" \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX="/usr" \
    -DCMAKE_INSTALL_LIBDIR="lib" \
    -DBUILD_SHARED_LIBS=ON \
    ./
  make -C "_build"
}

check() {
  cd "nuspell"

  make -C "_build" test
}

package() {
  cd "nuspell"

  make -C "_build" DESTDIR="$pkgdir" install
}