PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35

# Maintainer: Evzen Demcenko
# Contributor: Gustavo Castro < gustawho [ at ] gmail [ dot ] com >
# Contributor: xylosper <darklin20@gmail.com>
# Contributor: Martin T. H. Sandsmark <martin.sandsmark@kde.org>

pkgname=okular-backend-mupdf-git
pkgver=r94.fe6965e
pkgrel=1
pkgdesc="MuPDF-based backend for Okular (git)"
arch=('x86_64')
license=('AGPL')
depends=('gcc-libs' 'glibc' 'kcoreaddons' 'ki18n' 'libmupdf' 'okular' 'qt6-base')
makedepends=('extra-cmake-modules' 'git')
url="https://github.com/lanconnected/okular-backend-mupdf"
source=("git+${url}.git")
sha1sums=('SKIP')
conflicts=("okular-backend-mupdf")
provides=("okular-backend-mupdf-git")

pkgver() {
  cd ${pkgname%-git}
  ( set -o pipefail
    git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  )
}

build() {
  cmake -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_BUILD_TYPE=RelWithDebInfo -B build -S ${pkgname%-git}
  cmake --build build --config RelWithDebInfo
}

package() {
  DESTDIR="${pkgdir}" cmake --install build --config RelWithDebInfo
}