PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68

# Maintainer: yhtez <yhtez@protonmail.com>
pkgname=olympus
pkgver=25.03.02.03
_commit=904cbf2fc58bd944161d22d7acd1267fbcc13d48
pkgrel=1
pkgdesc='Everest installer / mod manager for Celeste'
arch=('x86_64')
url='https://github.com/EverestAPI/Olympus'
license=('MIT')
depends=('dotnet-runtime-8.0' 'gtk3' 'love' 'lua51-lsqlite3')
makedepends=('dotnet-sdk-8.0' 'git' 'lua51' 'luarocks')
conflicts=('olympus-bin')
source=("git+https://github.com/EverestAPI/Olympus.git#commit=$_commit"
        "git+https://github.com/EverestAPI/OlympUI.git"
        "git+https://github.com/vrld/moonshine.git"
        "git+https://github.com/LPGhatguy/luajit-request.git"
        "git+https://github.com/maddie480/lua-subprocess.git#commit=786303cd172bf8eb8f88c5998603875f3c33974c"
        "git+https://github.com/Vexatos/nativefiledialog.git#commit=bea4560b9269bdc142fef946ccd8682450748958")
sha256sums=('54d010f24e6231cf9391b9354902e991d4cee661b68d896d280c304817b9fd03'
            'SKIP'
            'SKIP'
            'SKIP'
            'b47289e5833c6aa1576237a8a191f33e9da101bd45bf7f550da64a5d19bc9c99'
            '4badf24e80989d7e0f5662b3ecea9013745de11dd9b1194be1149a4c753ed1ed')

prepare() {
    cd "$srcdir/Olympus"

    git submodule init
    git config submodule.src/ui.url "$srcdir/OlympUI"
    git config submodule.src/moonshine.url "$srcdir/moonshine"
    git config submodule.src/luajit-request.url "$srcdir/luajit-request"
    git -c protocol.file.allow=always submodule update

    printf "%s" "$pkgver" > src/version.txt
}

build() {
    cd "$srcdir/Olympus"

    dotnet build --configuration Release sharp/Olympus.Sharp.sln
    dotnet publish --configuration Release sharp/Olympus.Sharp.sln --output sharp/publish

    cd "$srcdir/lua-subprocess"; luarocks make --lua-version=5.1 --tree="$srcdir/Olympus/luarocks" --deps-mode=none --no-manifest subprocess-scm-1.rockspec
    cd "$srcdir/nativefiledialog"; luarocks make --lua-version=5.1 --tree="$srcdir/Olympus/luarocks" --deps-mode=none --no-manifest lua/nfd-scm-1.rockspec \
        LUA_LIBDIR=/usr/lib # nfd requires this env variable since it (incorrectly?) uses it for -L and it isn't set by default by luarocks
}

package() {
    cd "$srcdir/Olympus"

    mkdir -p "$pkgdir/usr/lib/olympus"
    mkdir -p "$pkgdir/usr/bin"
    ln -s /usr/lib/olympus/olympus "$pkgdir/usr/bin/olympus"
    install -Dm755 olympus.sh "$pkgdir/usr/lib/olympus/olympus"
    install -Dm755 find-love.sh "$pkgdir/usr/lib/olympus/find-love"
    install -Dm755 suppress-output.sh "$pkgdir/usr/lib/olympus/suppress-output"

    bsdtar --format zip --strip-components 1 -cf "$pkgdir/usr/lib/olympus/olympus.love" src

    install -Dm755 luarocks/lib/lua/5.1/* -t "$pkgdir/usr/lib/olympus"
    cp -dr --no-preserve='ownership' sharp/publish "$pkgdir/usr/lib/olympus/sharp"

    install -Dm644 lib-linux/olympus.desktop "$pkgdir/usr/share/applications/olympus.desktop"
    install -Dm644 src/data/icon.png "$pkgdir/usr/share/icons/hicolor/128x128/apps/olympus.png"

    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}