PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Maintainer: redtide <redtid3@gmail.com>

_pkgname=omgmounter
pkgname=$_pkgname-git
pkgver=r13.86e3081
pkgrel=1
pkgdesc="CDEmu CD/DVD image mounter frontend"
arch=(
  i686
  pentium4
  x86_64
)
url="https://github.com/qtilities/omgmounter"
license=(GPL3)
makedepends=(
  cmake
  doxygen
  git
)
depends=(
  cdemu-client
  libstatusnotifieritem-qt6
  qt6-base
)
provides=(${_pkgname})
conflicts=(${_pkgname})
source=(git+$url.git)
sha512sums=('SKIP')

pkgver() {
  cd $_pkgname
  (
    set -o pipefail
    git describe --long --tags 2>/dev/null | sed 's/^v//; s/\([^-]*-g\)/r\1/;s/-/./g' ||
      printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  )
}

build() {
  local cmake_options=(
    -B build
    -D CMAKE_INSTALL_PREFIX=/usr
    -D CMAKE_BUILD_TYPE=None
    -D PROJECT_QT_VERSION=6
    -S "$srcdir/$_pkgname"
    -W no-dev
  )
  cmake ${cmake_options[@]}
  cmake --build build --verbose
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}