blob: 87c3812b3face005d1a9c8a5b811fecc49ae9526 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: bgme <i@bgme.me>
# Contributor: ml <>
_pkgname=probe-cli
pkgname=ooniprobe-cli
pkgver=3.25.0
_pkgver=3.25.0
pkgrel=1
pkgdesc='Next generation OONI Probe CLI'
arch=('x86_64')
url='https://ooni.org/'
license=('GPL-3.0-or-later')
depends=('glibc')
makedepends=('go')
source=("${_pkgname}-${_pkgver}.tar.gz::https://github.com/ooni/${_pkgname}/archive/refs/tags/v${_pkgver}.tar.gz")
sha256sums=('9222fb2d0b93ba1bf4cf7edcee7dfac6518fc622d606204724d8ed7de43fb5dd')
sha512sums=('caad1ac4ff990a9d58c1bc2cce9eb7d8222f435741a364e6044987087ed3788a86d9cff6cd47b544ebbbbf03f31b21805e73c3c187e8bd9d399b70011c51c00a')
build() {
cd "${_pkgname}-${_pkgver}"
GOVERSION=$(cat GOVERSION)
export GOTOOLCHAIN=go${GOVERSION}
export CGO_ENABLED=1
export CGO_LDFLAGS="$LDFLAGS"
export CGO_CFLAGS="$CFLAGS"
export CGO_CPPFLAGS="$CPPFLAGS"
export CGO_CXXFLAGS="$CXXFLAGS"
export GOFLAGS='-ldflags=-linkmode=external -buildmode=pie -trimpath -modcacherw'
go build ./cmd/ooniprobe
}
package() {
cd "${_pkgname}-${pkgver}"
install -Dm755 ooniprobe -t "$pkgdir/usr/bin"
install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
install -Dm644 Readme.md -t "$pkgdir/usr/share/doc/$pkgname"
}
|